Comment utiliser la fonction UNIQUE sur plusieurs colonnes d'un tableau ?

Extraire sans doublon sur une colonne

La fonction UNIQUE permet d'extraire les valeurs uniques d'une colonne sélectionnée.

Extraire sur 2 colonnes contiguës

Si l'extraction concerne 2 colonnes contiguës (c'est à dire, l'une à coté de l'autre), la fonction UNIQUE retourne également l'unicité mais sur l'association des 2 colonnes.

La marque "Noke" est présente plusieurs fois car nous avons plusieurs couleurs de chaussures en stock pour cette marque mais chaque association (Marque + Couleur), est unique.

La formule avec un tableau est

=UNIQUE(Table1[[Col1]:[Col2]])

Et avec des références de cellules classiques c'est

=UNIQUE($A$1:$B$12)

Extraction sur des colonnes séparées

Maintenant, pour utiliser la fonction UNIQUE sur plusieurs colonnes qui sont séparées, la construction de la fonction est beaucoup plus hardues.

Il faut tout d'abord comprendre que le premier paramètre attendu par la fonction UNIQUE n'est pas une colonne mais un tableau. Il faut comprendre ici un tableau comme un tableau en mémoire. Et une colonne, ce n'est ni plus ni moins qu'un tableau mais sur une seule dimension.

Et la fonction FILTRE, retourne un tableau de données ???? Donc, la solution c'est de construire le tableau de données dans lequel nous allons extraire les données grâce à la fonction FILTRE.

Nous avons vu dans cet article comment se servir des opérateurs logiques pour réaliser des extractions complexes dans la fonction FILTRE. Et nous allons utiliser la même logique pour construire notre tableau. IL EST IMPORTANT DE SUIVRE LE LIEN POUR COMPRENDRE LA LOGIQUE.

Si par exemple, nous voulons "construire" un tableau en mémoire avec seulement le modèle et la couleur, nous allons écrire la formule suivante

=FILTRE(Chaussures;(Chaussures[#En-têtes]="Modèle")+(Chaussures[#En-têtes]="Couleur"))

Il ne reste plus qu'à intégrer cette formule, dans la formule UNIQUE pour extraire les colonnes séparées.

=UNIQUE(FILTRE(Chaussures;(Chaussures[#En-têtes]="Modèle")+(Chaussures[#En-têtes]="Couleur")))

Ou, si nous n'utilisons pas les références d'un tableau, nous écrivons la formule comme ceci.

=UNIQUE(FILTRE($A$2:$E$199;($A$1:$E$1="Modèle")+($A$1:$E$1="Couleur")))