Fonction LET – Optimiser vos formules

Temps de lecture : 3 minutes

La fonction LET est une fonction particulière dans Excel. Elle a pour seul but d'optimiser l'exécution d'une formule.

Pourquoi optimiser une formule Excel ?

Avant toute chose, il faut faire la différence entre une formule et une fonction

  • Une fonction, c'est une fonction interne à Excel (SOMME, SI, RECHERCHEX, ...)
  • Une formule c'est le résultat d'une ou plusieurs fonctions (en clair, le contenu d'une cellule c'est une formule qui utilise plusieurs fonctions)

Si vous construisez des formules qui utilisent plusieurs fonctions gourmandes en mémoire, vos classeurs seront nécessairement lourd et ralentis.

Fonctions Volatiles

Dans Excel, certaines fonctions sont volatiles (comme AUJOURDHUI, INDIRECT, DECALER, ...). Ces fonctions sont en permanences recalculées ; mais vraiment 😲

Sans action de votre part, sans recalcul, sans rien, à partir du moment où votre classeur contient l'une de ces fonctions, votre classeur va solliciter en permanence la mémoire de votre ordinateur. Si vous utilisez fréquemment ces formules, votre classeur sera nécessairement lent 💡

Simplification d'une fonction

Dans certaines formules, une même fonction peut être utilisées plusieurs fois. Comme dans cet exemple.

=SI(ESTNA(RECHERCHEV(D2;A2:B21;2;0));"";RECHERCHEV(D2;A2:B21;2;0))

Dans ce cas de figure, la fonction RECHERCHEV est évaluée à 2 reprises

  • Une fois dans le test
  • Une autre fois pour retourner le résultat.

Principe de la fonction LET

La fonction LET va mettre en variable une constante ou une formule pour être réutilisée dans le dernier paramètre de la fonction.

=LET(Variable1;Contenu;Variable2;Contenu;.....;Variable1+Variable2)

  • La fonction LET n'est présente qu'avec les versions de Microsoft 365 et Excel Online
  • Vous pouvez améliorer le visuel de la fonction en insérant des sauts de ligne avec le raccourci-clavier Alt+Entrée
  • Le nom d'une variable ne peut pas commencer par un nombre ni par un symbole

Cas pratique d'utilisation de la fonction LET

Simplification de la fonction RECHERCHEV

La formule suivante affiche l'email quand le prénom est présent dans la liste. Ici, nous utilisons 2 fois la même instruction RECHERCHEV et cette fonction est évaluée 2 fois.

=SI(ESTNA(RECHERCHEV(D2;A2:B21;2;0));"";RECHERCHEV(D2;A2:B21;2;0))

Fonction RECHERCHEV email

Pour simplifier cette fonction, nous allons écrire la fonction LET de la façon suivante

=LET(Result;RECHERCHEV(D2;A2:B21;2;0);
SI(ESTNA(Result);"";Result))

  1. Nous mettons la fonction RECHERCHEV(D2;A2:B21;2;0) dans la variable Result
  2. Cette variable est réutilisée 2 fois dans l'évaluation de la formule
Fonction LET pour simplifier lecriture de RECHERCHEV

Le résultat est exactement le même mais avec cette écriture, la fonction RECHERCHEV n'a été utilisée qu'une seule fois dans la formule.

Simplification de la fonction DATE

La formule du calcul d'une date en fonction du numéro de semaine utilise plusieurs fois la fonction DATE.

=DATE(Année;1;1)+SI(JOURSEM(DATE(Année;1;1);2)<5;(Sem-1)*7;Sem*7)-JOURSEM(DATE(Année;1;1);2)+1

Fonction qui retourne une date a partir dun numero de semaine

Première simplification

Ici, nous allons mettre en variable la formule DATE et la formule JOURSEM

=LET(
Janv1;DATE(A2;1;1);
Jour1;JOURSEM(DATE(A2;1;1);2);
Janv1+SI(Jour1<5;(B$1-1)*7;B$1*7)-Jour1+1)

Fonction LET pour simplifier lecriture du calcul de la date

Deuxième simplification

Mais si vous regardez plus attentivement la construction de la formule, vous pouvez voir que la fonction DATE est utilisée également dans la fonction JOURSEM. Ainsi, nous allons pouvoir modifier la seconde variable en réutilisant la première 😲👍

=LET(
Janv1;DATE(A2;1;1);
Jour1;JOURSEM(Janv1;2);
Janv1+SI(Jour1<5;(B$1-1)*7;B$1*7)-Jour1+1)

Reutilisation de la variable dans la fonction LET

Vidéo

2 Comments

  1. Mallard Dominique
    21/01/2022 @ 10:35

    Merci beaucoup pour cette information. Je comprends pourquoi mon pc rame, voire plante maintenant sur mes fichiers Excel. Je vais repenser mes formules.

    Reply

    • Frédéric LE GUEN
      21/01/2022 @ 11:20

      Top. Je vais rajouter la vidéo la semaine prochaine

      Reply

Laisser un commentaire

Votre adresse e-mail ne sera pas publiée. Les champs obligatoires sont indiqués avec *

Ce site utilise Akismet pour réduire les indésirables. En savoir plus sur comment les données de vos commentaires sont utilisées.

MICROSOFT MVP

RECHERCHE D’EMPLOI AVEC