Si vous travaillez sur des tableaux de plusieurs dizaines de colonnes, cet article, va vous montrer comment la fonction CHOISIRCOLS va vous aider à reconstituer un tableau en utilisant les noms des colonnes.

Les données sont dans un Tableau afin de simplifier leurs sélections.

Etape 1 : Présentation de la fonction CHOISIRCOLS

Par exemple, si nous voulons retourner le prénom, le nom de famille et la ville, voici la formule que nous devons écrire

=CHOISIRCOLS(tbl_Clients;3;5;7)

Etape 2 : Créer un menu déroulant

Nous allons créer un menu déroulant en prenant comme source la ligne d'en-têtes du Tableau

Etape 3 : Convertir le nom d'une colonne en position

A partir du menu déroulant, il est maintenant facile de choisir le titre de l'une des colonnes.

Il faut maintenant trouver le numéro de colonne associé au nom sélectionné. Pour cela, il y a la fonction EQUIV.

=EQUIV(C24;tbl_Clients[#En-têtes];0)

Etape 4 : Ajouter EQUIV dans CHOISIRCOLS

Grâce à ce résultat, nous allons remplacer la sélection de la première colonne par la fonction précédente.

=CHOISIRCOLS(tbl_Clients;EQUIV(C24;tbl_Clients[#En-têtes];0))

Etape 5 : Adapter pour plusieurs colonnes

Maintenant, pour retourner plusieurs colonnes, nous allons changer le premier paramètre de la fonction EQUIV pour prendre en compte toutes les colonnes que nous voulons retourner.

=CHOISIRCOLS(tbl_Clients;EQUIV(C24:E24;tbl_Clients[#En-têtes];0))

Mais il reste un dernier problème à résoudre. La plage de cellules de la fonction EQUIV ne peut pas contenir de cellules vides. Il faut donc trouver une autre solution pour prendre en compte les cellules vides

Etape 6 : RECHERCHEX retourne une référence.

C'est la partie la plus difficile de cet article.

Il existe 2 fonctions dans Excel qui permettent de retourner un résultat ou bien la référence d'une cellule ; il s'agit des fonctions INDEX et RECHERCHEX. Nous avons vu comment utiliser cette fonctionnalité pour faire une somme dynamique.

Ici, nous allons construire une fonction RECHERCHEX qui va récupérer la dernière cellule renseignée dans une plage de données.

=RECHERCHEX(FAUX;ESTVIDE(C24:I24);C24:I24;;;-1)

La partie importante, c'est le deuxième paramètre. Ici, on construit un tableau de FAUX (cellule non vide) ou VRAI (cellule vide).

Et on recherche le dernier paramètre -1

Il nous reste à remplacer la seconde référence de la plage dans la fonction EQUIV par la fonction RECHERCHEX. La formule complète et adaptable à toutes les situations est la suivante

=CHOISIRCOLS(tbl_Clients;EQUIV(C24:
RECHERCHEX(FAUX;ESTVIDE(C24:I24);C24:I24;;;-1);
tbl_Clients[#En-têtes];0))

Télécharger le fichier avec la formule complète

Autre solution

Gaetan Mourmant, un autre Microsoft MVP, propose la solution suivante avec FILTRE, SEQUENCE, EXCLURE et LET

=LET(ZonePlageTout;tbl_Clients[#Tout ];Zone_Filtre;C24:M24;
Zone_Plage;EXCLURE(ZonePlageTout;1);
Zone_Plage_EnTete;EXCLURE(ZonePlageTout;1-LIGNES(ZonePlageTout));
FILTRE(Zone_Plage;RECHERCHEX(Zone_Plage_EnTete;FILTRE(Zone_Filtre;Zone_Filtre<>"");
SEQUENCE(1;COLONNES(FILTRE(Zone_Filtre;Zone_Filtre<>""));1;0);0)))

Vidéo

Retrouver toutes les explications dans la vidéo suivante