Premier jour ou dernier jour dans Excel

Frédéric LE GUEN

il y a 5 ans

Formules pour retourner le premier et dernier lundi du mois

Dans cette page, vous trouverez les formules qui calculent certains jours particuliers automatiquement.

Nous utilisons la fonction AUJOURDHUI pour les exemples mais vous remplacerez cette donnée par le contenu de vos cellules.

Premier et dernier jour du mois courant

Ces deux calculs sont assez facile à réaliser et se construisent avec la fonction DATE

1^er jour du mois

=DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI());1)

Dernier jour du mois

En se basant sur la règle que 1 est obligatoirement 1 jour dans Excel, nous allons faire une formule qui va construire le 1^er jour du mois suivant et nous retranchons 1

=DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI())+1;1)-1

ou en utilisant la fonction FIN.MOIS

=FIN.MOIS(AUJOURDHUI();0)

Premier / Dernier jour du mois précédent

Les formules pour trouver le premier et dernier jour du mois précédent se construisent de la même façon

1^er jour du mois précédent

=DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI())-1;1)

Dernier jour du mois précédent

En se basant sur la règle que 1 est obligatoirement 1 jour dans Excel, nous allons faire une formule qui va construire le premier jour du mois suivant et nous retranchons 1

=DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI());1)-1

=DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI());0)

Premier / Dernier lundi

Pour trouver le prochain lundi ou le précédent lundi à partir de n'importe quelle date, suivez ce lien pour découvrir toutes les formules.

Premier et dernier jour de l'année

1^er jour de l'année

=DATE(ANNEE(AUJOURDHUI());1;1)

Dernier jour de l'année

=DATE(ANNEE(AUJOURDHUI())+1;1;1)-1

ou en remplaçant par un 0 pour indiquer le jours précédents

=DATE(ANNEE(AUJOURDHUI())+1;1;0)

Premier lundi de l'année

Ici, nous allons nous servir de la fonction JOURSEM pour obtenir ce résultat

=DATE(ANNEE(AUJOURDHUI());1;8)-JOURSEM(DATE(ANNEE(AUJOURDHUI());1;6))

Dernier lundi de l'année

=DATE(ANNEE(AUJOURDHUI())+1;1;0)-JOURSEM(DATE(ANNEE(AUJOURDHUI());1;6))

Nombre de jours dans le mois

Une information très importante, et souvent ignorée, c'est le nombre de jours dans un mois. Pour des rapports mensuels, cette information est très importante. Les formules suivantes vous permette de retourner le nombre de jours dans 1 mois donné.

Nombre de jours dans le mois courant

=JOUR(DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI())+1;0))

Nombre de jours dans le mois suivant

=JOUR(DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI())+2;0))

Nombre de jours dans le mois précédent

=JOUR(DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI());0))