Dans cette page, vous trouverez les formules qui calculent certains jours particuliers automatiquement.
Nous utilisons la fonction AUJOURDHUI pour les exemples mais vous remplacerez cette partie par vos données.
Premier dernier jour dans le mois
Ces deux calculs sont assez facile à réaliser et se construisent avec la fonction DATE
Premier jour du mois
=DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI());1)
Dernier jour du mois
En se basant sur la règle que 1 est obligatoirement 1 jour dans Excel, nous allons faire une formule qui va construire le premier jour du mois suivant et nous retranchons 1
=DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI())+1;1)-1
ou en utilisant la fonction FIN.MOIS
=FIN.MOIS(AUJOURDHUI();0)
Premier / Dernier jour du mois précédent
Les formules pour trouver le premier et dernier jour du mois précédent se construisent de la même façon
Premier jour du mois précédent
=DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI())-1;1)
Dernier jour du mois précédent
En se basant sur la règle que 1 est obligatoirement 1 jour dans Excel, nous allons faire une formule qui va construire le premier jour du mois suivant et nous retranchons 1
=DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI());1)-1
Ou
=DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI());0)
Premier / Dernier lundi
Pour trouver le prochain lundi ou le précédent lundi à partir de n'importe quelle date, suivez ce lien pour découvrir toutes les formules.
Premier dernier jour de l'année
Premier jour de l'année
=DATE(ANNEE(AUJOURDHUI());1;1)
Dernier jour de l'année
=DATE(ANNEE(AUJOURDHUI())+1;1;1)-1
ou en remplaçant par un 0 pour indiquer le jours précédents
=DATE(ANNEE(AUJOURDHUI())+1;1;0)
Premier lundi de l'année
=DATE(ANNEE(AUJOURDHUI());1;8)-JOURSEM(DATE(ANNEE(AUJOURDHUI());1;6))
Dernier lundi de l'année
=DATE(ANNEE(AUJOURDHUI())+1;1;0)-JOURSEM(DATE(ANNEE(AUJOURDHUI());1;6))
Nombre de jours dans le mois
Une information très importante, et souvent ignorée, c'est le nombre de jours dans un mois. Pour des rapports mensuels, cette information est très importante.
Les formules suivantes vous permette de retourner le nombre de jours dans 1 mois donné.
Nombre de jours dans le mois courant
=JOUR(DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI())+1;0))
Nombre de jours dans le mois suivant
=JOUR(DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI())+2;0))
Nombre de jours dans le mois précédant
=JOUR(DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI());0))
GOUEZ29
NUL_EN_EXCEL
Jean-Luc OSMONT
Frédéric LE GUEN
Marc ANDRE
Rylewski
28/06/2021 @ 13:33
Bonjour,
Existe t-il une formule pour réaliser ce genre d'opération:
"Dernière année se commençant par un Samedi"
"Liste des années se terminant par un dimanche"
"Prochaines années se terminant par tel jour"
par exemple?
D'avance merci,
Pierre GOUEZ
03/05/2021 @ 10:28
Bonjour
quelle formule faut il mettre en œuvre pour obtenir le MOIS en cours moins une journée
car j'ai un problème avec un fichier en auto, la base se met à jour chaque nuit mais les fichiers sont envoyés en automatique le lendemain
cela fonctionne parfaitement bien avec la fonction MOMIS = aujourd'hui) sauf pour le 1er jour du mois suivant ou les données sont à 0 car la base est du mois précèdent.
28/12/2020 @ 13:48
Bonjour Frédéric, et merci pour vos nombreux tutos concernant excel, c'est passionnant !
Je n'arrive pas à trouver comment faire une mise en forme conditionnelle lorsqu'une cellule est le 1er jour du mois !
ça doit être tout simple mais j'y arrive pas, même en mettant la formule que vous donnez en début de tuto.
En fait, j'aurais même préféré que la mise en forme conditionnelle apparaisse dans une autre cellule (par exemple A1), afin d'avoir juste une couleur qui apparait quand la cellule (par exemple A2) contenant la date est le 1er jour du mois.
Merci pour votre aide, si tant est que ce soit faisable.
28/12/2020 @ 14:49
=JOUR(MaDate)=1
10/02/2021 @ 22:29
Bonjour,
Je souhaite faire quelque chose de comparable à Jean-Luc mais je ne comprends pas votre réponse.
Je pensais faire "=SI((case à sélectionner)=(premier jour d'un mois);(donnée à insérer)) mais je ne sais pas comment dire à Excel "premier jour d'un mois".
D'avance merci pour votre aide.
11/02/2021 @ 09:49
Bonjour, mais la formule est justement expliquée dans l'article
15/11/2018 @ 10:30
Petite typo dans votre première formule du dernier jour du mois, vous avez écrit :
=DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI()+1);1)-1
alors que pour que cela fonctionne, il faudrait :
=DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI())+1;1)-1
Un point de détail mais le diable est dans les détails !
Sinon excellent post, merci à vous !
15/11/2018 @ 10:39
Bien vu
D'autres articles similaires sont en cours. Dont un bien compliqué avec les semaines