«

»

Glossaires des dates complexes dans Excel

Cet article présente l'ensemble des formules qui vous permettent de calculer des dates remarquables comme le premier jour du mois, le dernier jour du mois, le premier lundi d'une semaine, le premier lundi de la semaine suivante, ...)

Toutes les formules sont basées sur la date du jour AUJOURDHUI et sont intégrées dans Excel Online. Ainsi, vous pouvez voir les résultats des formules dans Excel.

Nombre de jours dans le mois

Excel vous permet de calculer le nombre de jours d'un mois donné. Ici vous sont présentées différentes techniques de calcul.

Nombre de jours dans le mois

=JOUR(DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI())+1;0))

=JOUR(DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI())+1;1)-1)

=32-JOUR(AUJOURDHUI()-JOUR(AUJOURDHUI())+32)

Nombre de jours du mois précédent

=JOUR(AUJOURDHUI()-JOUR(AUJOURDHUI()))

Premier et dernier jour d'un mois

Excel vous permet de calculer n'importe quel jour d'un mois quelconque. C'est très intéressant pour la constitution d'un rapport qui s'actualise automatiquement chaque mois. Plusieurs écritures de formules sont possibles. Choisissez celle qui vous convient le mieux.

Date du premier jour du mois

=DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI());1)

=AUJOURDHUI()-JOUR(AUJOURDHUI())+1

Date du dernier jour du mois

=DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI())+1;0)

=DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI())+1;1)-1

=FIN.MOIS(AUJOURDHUI();0)

Date du dernier jour du mois suivant

=DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI())+2;1)-1

=FIN.MOIS(AUJOURDHUI();1)

Calcul sur les semaines

Il y a une différence sur les calculs des numéros de semaine entre l'Amérique du Nord et le reste du Monde. Comme la fonction NO.SEMAINE a été développée par Microsoft (aux Etats-Unis) la fonction retourne le nombre de semaines selon la méthode de calcul américaine. En Europe c'est la règle officielle ISO 8601 qui doit être appliquée.

Depuis la version d'Excel 2013, la fonction NO.SEMAINE.ISO corrige ce dysfonctionnement mais avant cette version, il était possible de calculer le numéro de semaine en Europe selon des méthodes de calculs beaucoup plus complexes

Numéro de semaine USA

=NO.SEMAINE(AUJOURDHUI())

Numéro de semaine ISO 8601 (Europe)

=ENT((AUJOURDHUI()-SOMME(MOD(DATE(ANNEE(AUJOURDHUI()-MOD(AUJOURDHUI()-2;7)+3);1;2);{1E+99;7})*{1;-1})+5)/7)

=ENT((AUJOURDHUI()-JOURSEM(AUJOURDHUI();2)+11-DATE(ANNEE(AUJOURDHUI()-JOURSEM(AUJOURDHUI();2)+4);1;1))/7)

=NO.SEMAINE(AUJOURDHUI();21)

=NO.SEMAINE.ISO(AUJOURDHUI())

Nombre de semaines ISO 8601 dans l'année

=52+ET(JOURSEM(DATE(ANNEE(AUJOURDHUI());{2;8};))>5)

Nombre de semaines dans le mois courant

=ENT((37+JOURSEM(AUJOURDHUI()-JOUR(AUJOURDHUI()))-JOUR(AUJOURDHUI()-JOUR(AUJOURDHUI())+32))/7)

Premier / dernier jour

Dans le document ci-dessous, vous avez la liste des premiers ou derniers jours particuliers dans le mois ou dans l'année.

Premier lundi de la semaine suivante (pas d'égalité possible)

=AUJOURDHUI()-JOURSEM(AUJOURDHUI()-1)+8

Date du premier lundi du mois

=AUJOURDHUI()-JOUR(AUJOURDHUI())+8-JOURSEM(AUJOURDHUI()-JOUR(AUJOURDHUI())+6)

Date du dernier lundi du mois

=DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI())+1;1)- JOURSEM(DATE(ANNEE(AUJOURDHUI()); MOIS(AUJOURDHUI())+1;6))

Date du premier lundi de l'année

=DATE(ANNEE(AUJOURDHUI());1;8)- JOURSEM(DATE(ANNEE(AUJOURDHUI());1;6))

Date du dernier lundi de l'année

=DATE(ANNEE(AUJOURDHUI())+1;1;0)- JOURSEM(DATE(ANNEE(AUJOURDHUI());1;6))

Dernier jour ouvré de l'année

=DATE(ANNEE(AUJOURDHUI())+1;1;1)-1- (JOURSEM( DATE(ANNEE(AUJOURDHUI())+1 ;1;1)-1;2)>5)- (JOURSEM(DATE(ANNEE(AUJOURDHUI())+1;1;1)-1;2)>6)

Toujours le samedi précédent ou égal

=ENT(AUJOURDHUI()/7)*7

Jours fériés variables

Le jour de Pâques détermine les autres jours fériés du calendrier chrétien (Ascension, Pentecôte). Les formules suivantes vous permettent de déterminer les différents jours de fériés variables quelque soit l'année. De même, vous trouverez les formules pour trouver la date de Thanksgiving aux Etats-Unis et au Canada.

Jour de Pâques

=ARRONDI(DATE(ANNEE(AUJOURDHUI());4; MOD(234-11* MOD(ANNEE(AUJOURDHUI());19);30))/7;)*7-6

Lundi de Pâques

=Jour de Pâques+1

Jeudi de l'Ascension

=Jour de Pâques+39

Lundi de la Pentecôte

=Jour de Pâques+50

Thanksgiving (US)

=DATE(ANNEE(AUJOURDHUI());11; CHOISIR(JOURSEM(DATE(ANNEE(AUJOURDHUI());11;1)); 26;25;24;23;22;28;27))

Thanksgiving (Canada)

=DATE(ANNEE(AUJOURDHUI());10; CHOISIR(JOURSEM(DATE(ANNEE(AUJOURDHUI());10;1)); 9;8;14;13;12;11;10))

 

Articles complémentaires


Voici une liste d'articles qui pourrait également vous intéresser sur le même thème.

Lien Permanent pour cet article : https://www.excel-exercice.com/glossaires-des-dates-complexes-dans-excel/


Laisser un commentaire

Votre adresse de messagerie ne sera pas publiée. Les champs obligatoires sont indiqués avec *