Formatez les dates dans vos titres avec TEXTE

La fonction TEXTE vous permet d'afficher des données numériques sous un format personnalisé.

Présentation de la fonction TEXTE

En fait, cette fonction aurait dû s'appeler FORMAT car le terme TEXTE est ambigu. Le nom de cette fonction renvoie plutôt aux fonctions texte (DROITE, GAUCHE, NBCAR, ...) mais bon, c'est ainsi 😖🤨

Cette fonction va modifier l'affichage des nombres tout comme nous pouvons le faire avec une mise en forme des nombres ou des dates. Mais cette fois-ci, de façon dynamique 😉

La fonction TEXTE a 2 paramètres

• Une valeur numérique
• Le code du format à afficher

Problème avec l'affichage des dates

Si vous souhaitez afficher une date avec du texte dans une formule, comme par exemple "Rapport du 01 janvier au 31 janvier", la date s'affichera sans format 😱😱😱

C'est dans ce cas de figure que nous devons utiliser la fonction TEXTE 😉

Création d'un titre dynamique entre le premier est dernier jour du mois

Comment créer le titre d'un tableau de bord avec la première et la dernière date du mois courant ?

Construction de la première date du mois

Pour commencer, la première date d'un mois se construit grâce à la fonction DATE comme cela a été vu dans cet article.

Nous écrirons donc :

=DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI());1)

Mise en forme de la date

Maintenant, nous intégrons cette formule dans une fonction TEXTE. Pour afficher la date suivante de "01 Avril", nous allons utiliser les mêmes paramètres que le format d'une date, soit

jj mmmm

La formule s'écrit alors de la façon suivante :

=TEXTE(DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI());1);"jj mmmm")

Construction de la dernière date du mois

Trouver le dernier jour du mois s'obtient avec la formule suivante (cf article sur les premiers et derniers jours)

=DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI())+1;1)-1

Ou encore

=FIN.MOIS(AUJOURDHUI(),0)

Une nouvelle fois, nous insérons cette formule dans une fonction TEXTE pour afficher uniquement le jour et le mois

=TEXTE(DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI())+1;1)-1;"jj mmmm")

Associer les 2 fonctions ensemble 😉

Vous pouvez aussi écrire dans une même formule le titre de votre rapport et liant les 2 formules avec le caractère de liaison &.

La formule finale devient :

="Rapport du "&TEXTE(DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI());1);"jj mmmm")&" au "&TEXTE(DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI())+1;1)-1;"jj mmmm")