Calendrier hebdomadaire

Temps de lecture 4 minutes

Cet article va vous montrer comment créer un calendrier hebdomadaire, pour l'année 2020, avec seulement 1 formule dans Office 365 😉

Calendrier hebdomadaire 2020
Calendrier hebdomadaire 2020

Etes-vous Office Insider ?

Pour créer un calendrier hebdomadaire avec une seule formule, nous utiliserons la nouvelle fonction SEQUENCE. Cette fonction n'est accessible que si vous êtes Office Insider

Lorsque vous êtes Office Insider, vous avez accès à des fonctions spécifiques comme les fonctions matricielles dynamiques et aussi aux fonctions en cours de développement, comme la fonction RECHERCHEX.

Bouton Office Insider

Étape 1: créer la formule du premier jour

Pour calculer le premier jour d'un mois, nous avons besoin de la fonction DATE

=DATE($C$2,$C$3,1)

Si vous personnalisez le format de la date , vous pouvez voir que le 1er janvier 2020 est un mercredi. Et si vous changez le format en Standard , vous avez le numéro 43831. Comprendre cette astuce est important pour la suivante .

Formule pour calculer le premier jour du mois

Étape 2: Écrire le premier jour du mois en en-tête de calendrier

Afin de simplifier la formule de construction du calendrier hebdomadaire, nous allons placer cette formule en entête de notre calendrier.

Date dans le titre du calendrier

Bien sûr, le format de la date doit être personnalisé pour renvoyer le nom du mois et l'année. Le code à renseigner est le suivant

Menu Autres formats numériques

mmm aaaa

Mise au format de la date dans le titre

Etape 3 : Transformer la formule pour commencer toujours le même jours (lundi ou dimanche)

Traditionnellement, un calendrier hebdomadaire commence un lundi (et un dimanche dans le système américain). Donc, il faut modifier la formule précédente pour que nous affichions toujours le premier lundi quelques soit le mois sélectionné

=SI(JOURSEM(B5;3)=7;B5;B5-JOURSEM(B5;3))

Pour vérifier que la première date est bien un lundi, il suffit de changer le format de la date en utilisant le code

jjj jj/mm/aaaa

Formule pour calculer le lundi précédent

Pour faire commencer votre calendrier un dimanche, la formule est

=SI(JOURSEM(B5;2)=7;B5;B5-JOURSEM(B5;2))

Etape 4 : Créer une liste de jours avec SEQUENCE

Maintenant, nous devons construire tous les autres jours de notre calendrier hebdomadaire. Et ceci se fait très facilement avec la nouvelle fonction matricielle dynamique SEQUENCE. Cette fonction a 4 paramètres.

  • Le nombre de lignes (6 pour couvrir toutes les situations de calendrier)
  • Le nombre de colonnes (facile c'est 7, il y a toujours 7 jours dans une semaine)
  • La valeur de départ, c'est la formule précédente
  • Et enfin 1, le nombre de jour d'écart

=SEQUENCE(6;7; SI(JOURSEM(B5;3)=7;B5;B5-JOURSEM(B5;3));1)

Série de dates avec la fonction SEQUENCE

Maintenant, pour comprendre la logique, il suffit de changer le format des nombres en format Général pour voir que la fonction a créé une liste de valeur entre 43829 et 43870

Série de nombre au format standard

Étape 5: Personnalisez le format de la date

Dans cet article vous a été présenté comment changer le format des dates.

Ici, nous voulons afficher uniquement la valeur du jour. Le code a écrite dans la personnalisation des nombres c'est tout simplement la lettre j

j

Format des nombres dans le calendrier

Et maintenant, nous avons seulement les jours dans le calendrier hebdomadaire

Affichage des jours dans le calendrier hebdomadaire

Étape 6: Changer la couleur des jours

Afin d'avoir une meilleure visualisation des jours, nous allons changer les couleurs des jours avec une Mise en forme conditionnelle > Nouvelle règle en construisant nos propres formules

Menu Mise en forme conditionnelle Nouvelle règle

Règle pour le jour du mois sélectionné

La première règle pour tester si les dates sont dans le mois sélectionné est de comparer si le mois de la date dans B7 est égal au numéro du mois dans C3. Le format à appliquer est une couleur de police en noir et en gras.

=MOIS(B7)=$C$3

Le $ pour bloquer les références ou non est très important ici. MOIS (B7) est une référence relative pour lire toutes les cellules de notre calendrier et $ C $ 3 est bloqué le mois sélectionné

Règle pour les autres jours, ceux qui ne sont pas du mois

La formule pour mettre en évidence les jours non dans le mois sélectionné est très simple

=MOIS(B7)<>$C$3

Le format à appliquer dans cette situation est une couleur de police grise .

Règle pour les jours de week-end

Troisième règle, la couleur du jour est rouge et gras. La formule est donc

=ET(JOURSEM(B7;2)>5;MOIS(B7)=$C$3)

Toutes les règles de mises en forme

Voici les 3 règles créées dans le gestionnaire de règles

Les 3 mises en forme conditionnelles dans le gestionnaire

Le résultat final est votre calendrier hebdomadaire pour 2020.

Calendrier hebdomadaire finalisé

Articles complémentaires

Voici une liste d'articles qui pourrait également vous intéresser sur le même thème.

Lien Permanent pour cet article : https://www.excel-exercice.com/calendrier-hebdomadaire/

Laisser un commentaire

Your email address will not be published.

Ce site utilise Akismet pour réduire les indésirables. En savoir plus sur comment les données de vos commentaires sont utilisées.